لود اطلاعات SQL با استفاده از BackgroundWorker

سلام
من از کد زیر در جست و جو هام استفاده می کنم .

کد:

---

    Public Sub LoadDataGrid(ByVal Command As String, ByVal DataGridview As DataGridView)
        Try
            Using con As New SqlConnection(DeKrypt(My.Settings.ConnectionString))
                Dim da As New SqlDataAdapter("", con)
                Dim ds As New DataSet()
                ds.Clear()
                da.SelectCommand.CommandText = Command
                da.Fill(ds, "t1")
                DataGridview.DataSource = ds
                DataGridview.DataMember = "t1"
            End Using
        Catch ex As Exception

        End Try
    End Sub

---

میخوام وقتی که روی دکمه ی جست و جو وارد می کنم و این اطلاعات رو لود داره می کنه توی دیتا گرید یه فرم باز بشه شامل یه اسکرول بار و میزان لود شدن اطلاعات رو نشون بده و یه دکمه کنسل هم براش بزارم که وقتی کلیک شد از ادامه لود اطلاعات جلوگیری کنه.
البته دوستان روش BackgroundWorker رو پیشنهاد دادند . منم دنبالش روش و در این مورد چیز هایی رو هم پیدا کردم. اما نحوه جست و جوی اون ها به یک شکل دیگر بود و با کد جست و جوی من همخوانی نداشت و باید برای اینکه از اون روش استفاده کنم کل فانکشن هام رو تغییر بدم و به طور طبع کد هایی که از این تابع ها استفاده می کنه.
میخوام ببینم میشه توی این کد من هم همچین کاری کرد. ممنون میشم اگه کمک بفرمایید. :n16:

یعنی راهی نیست که بشه با این روش انجامش داد؟

سلام
میتوانید عملیات بارگذاری را در ریسمان مجزایی انجام دهید و در این بین هم یک تصویر gif یا پیامی برای انتظار نشان دهید ولی نشان دادن نوار پیشرفت (بیان درصد) کد زیادی میخواهد چون اغلب ORM های موجود این درصد را بیان نمیکنند و آن را پشتیبانی نمیکنند که البته تا حدودی هم حق دارند!

کد نمونه:

کد:

---

Public Sub LoadDataGrid(ByVal Sql As String)

        'Show 'please wait...' or  a '.gif' file  etc...
        '????.Visible = True
        'Me.Enabled = False

        System.Threading.ThreadPool.QueueUserWorkItem(AddressOf Me.AsyncLoadData, Sql)

End Sub

Private Sub AsyncLoadData(ByVal Sql As Object)

        Dim ds As New DataSet()
        Using da As New SqlDataAdapter(CStr(Sql), "---CONNECTIONSTRING---")
            da.Fill(ds, "t1")
        End Using

        Me.BeginInvoke(New Action(Of DataSet)(AddressOf Me.EndLoadData), ds)

End Sub

Private Sub EndLoadData(ByVal data As DataSet)

        Me.DataGridView1.DataSource = data
        Me.DataGridView1.DataMember = "t1"

        'Hide 'please wait...' or '.gif' file etc...
        '????.Visible = False
        'Me.Enabled = True

End Sub

---

بله ممنون.

نظرتون راجع به این کد چیه :

کد:

---

Private Sub Form18_Load(ByVal sender As Object, ByVal e As EventArgs)
        Dim conn As SqlConnection = New SqlConnection(connstr)
        Dim sql As String = "SELECT * FROM [Order Details]"
        da = New SqlDataAdapter(sql, conn)
        AddHandler dt.RowChanged, AddressOf Me.dt_RowChanged
    End Sub
   
    Private connstr As String = ("Persist Security Info=False;Integrated Security=SSPI;" + "Initial Catalog=Northwind;server=localhost")
   
    Private da As SqlDataAdapter
   
    Private dt As DataTable = New DataTable
   
    Private Sub button1_Click(ByVal sender As Object, ByVal e As EventArgs)
        Me.progressBar1.Maximum = getRowCount
        Me.progressBar1.Value = 0
        dt.Clear
        da.Fill(dt)
        Me.dataGridView1.DataSource = dt
    End Sub
   
    Private Sub dt_RowChanged(ByVal sender As Object, ByVal e As DataRowChangeEventArgs)
        If (Me.progressBar1.Value  _
                    < (dt.Rows.Count - 1)) Then
            Me.progressBar1.Value = (Me.progressBar1.Value + 1)
        End If
    End Sub
   
    Private Function getRowCount() As Integer
        Dim count As Integer = 0
        Dim conn As SqlConnection = New SqlConnection(connstr)
        Dim sql As String = "SELECT COUNT(OrderID) FROM [Order Details]"
        Dim cmd As SqlCommand = New SqlCommand(sql, conn)
        Try
            conn.Open
            Dim dr As SqlDataReader = cmd.ExecuteReader
           
            While dr.Read
                count = CType(dr(0),Integer)
               
            End While
        Catch  As System.Exception
           
        Finally
            conn.Close
        End Try
        Return count
    End Function

---

نمیشه مثلا تعداد نتایج جست و جویی که به دست میاد رو با استفاده از دستور Count در اس کیو ال به دست آورد و سپس با یه دست اومدن هر سطر از جست و جو یک مقدار از 0 شروع کنه و تا رسیدن به مقدار count یکی یکی اضافه بشه و یا همچین چیزی؟
اصلا این روش ، روش حرفه ای و مناسبی هست؟!
ممنون از وقتی که میذارید.

سلام مجدد
ارائه نوار پیشرفت برای این منظور کلاً منطقی نیست:
1) ORM ها درصد خواندن اطلاعات را پشتیبانی نمیکنند.

2) اگر خودتان هم بخواهید اطلاعات را بخوانید مجبور میشوید یکبار Count بگیرید و یکبار هم بخوانید.
دستور Count برخلاف ظاهر ساده اش دستور پرهزینه است و نیاز است موتور دیتابیس یکبار کل پرس و جو را اجرا و نتایج را شمارش کند،
در واقع شما مجبور میشوید دوبار از دیتابیس استعلام بگیرید و در نهایت هم بجای ORM های موجود خودتان باید اطلاعات را بخوانید تا بدانید چند سطر را خوانده اید!!!

3) اصولاً بارگذاری اطلاعات شما از دیتابیس نباید آنقدر زمان بر باشد که نوار پیشرفت بخواهید.
حتی اگر عملیات تان چند ثانیه هم بطول بکشد باز نیازی به نوار پیشرفت نیست.
اگر هم حجم اطلاعات واکشی شده بسیار زیاد است (مثلاً چند ده هزار سطر) منطق آن است که یک مکانیزم صفحه بندی مناسب در برنامه تان پیاده سازی کنید تا بعنوان نمونه هربار فقط 100 سطر واکشی شود.

پیشنهاد میکنم به یک تصویر gif چرخان اکتفا کنید.
این مورد خیلی مرسوم و عادی است
بهتر است برای اعمالی که چندین دقیقه بطول میکشد در جهت پیاده سازی نوار پیشرفت تلاش کنید.
موفق باشید.

ممنون از راهنماییتون.
نمیشه همه ی این کد ها روی توی یه Sub نوشت ؟ آخه اینجوری که 3 تا شد . باعث میشه من مجبور بشم کل کدهام رو تغییر بدم و کلا به هم میریزه :n27:

و اینکه میشه یک این تصویر یا پیغام لطفا صبر کنید را در یک فرم دیگه قرار داد و در اون فرم یک دکمه انصراف قرار داد تا با کلیک روی اون عملیات متوقف بشه؟

سلام
اول در مورد پست سوم خودم باید عرض کنم که اشتباهاً در محل فراخوانی تابع EndLoadData مجدد AsyncLoadData درج شده بود که تصحیح کردم.

نقل قول:

---

نمیشه همه ی این کد ها روی توی یه Sub نوشت ؟ آخه اینجوری که 3 تا شد . باعث میشه من مجبور بشم کل کدهام رو تغییر بدم و کلا به هم میریزه

---

باید فقط دو تابع دیگر اضافه کنید، چرا باید کل کدها را تغییر دهید؟
اگر راضی تان میکند، اینطوری هم میشود و یک تابع هم خواهد بود! :n13:

کد:

---

Public Sub LoadDataGrid(ByVal Sql As String)

        'Show 'please wait...' or  a '.gif' file  etc...
        '????.Visible = True
        'Me.Enabled = False

        System.Threading.ThreadPool.QueueUserWorkItem(
                Sub(s)

                        Dim ds As New DataSet()
                        Using da As New SqlDataAdapter(CStr(s), "---CONNECTIONSTRING---")
                                da.Fill(ds, "t1")
                        End Using

                        Me.BeginInvoke(New Action(Of DataSet)(
                                Sub(data)

                                        Me.DataGridView1.DataSource = data
                                        Me.DataGridView1.DataMember = "t1"

                                        'Hide 'please wait...' or '.gif' file etc...
                                        '????.Visible = False
                                        'Me.Enabled = True

                                End Sub), ds)
                End Sub, Sql)
End Sub

---

نقل قول:

---

و اینکه میشه یک این تصویر یا پیغام لطفا صبر کنید را در یک فرم دیگه قرار داد

---

بله به سادگی

نقل قول:

---

در اون فرم یک دکمه انصراف قرار داد تا با کلیک روی اون عملیات متوقف بشه؟

---

چون حلقه پر کننده دیتاست داخل ORM است و به آن دسترسی نداریم، اگر بخواهیم عملیات را متوقف کنیم باید قبل عملیات اشاره گر ریسمان را ذخیره و درصورت لزوم آن را ناچار به Abort ریسمان خواهیم بود.
یک چیز تو مایه های مشابه EndTask یک برنامه در ویندوز!
من کدش را برایتان میگذارم (نگویید هرچه میخواهم، راه نمایی نمیکنند و آیه یاس میخوانند! :n02:)، ولی باور بفرمائید یک عملیات چند ثانیه ای ارزش این Abort را ندارد (حتی ارزش آن فرمی که بازشود را هم ندارد!)، احتمالاً در اکثر مواقع قبل از انکه کاربرتان متوجه شود و تصمیم بگیرید که میخواهد یا نمیخواهد عملیات را لغو/متوقف کند، عملیات تمام شده و رفته!!!

کد:

---

Private m_Thread As System.Threading.Thread

Public Sub OnCancel()
        Try
                Dim thread = Me.m_Thread
                If (thread IsNot Nothing) Then thread.Abort()
        Catch
        End Try
End Sub

Public Sub LoadDataGrid(ByVal Sql As String)

        'Show 'please wait...' or  a '.gif' file  etc...
        '????.Visible = True
        'Me.Enabled = False

        System.Threading.ThreadPool.QueueUserWorkItem(AddressOf Me.AsyncLoadData, Sql)

End Sub

Private Sub AsyncLoadData(ByVal Sql As Object)
        System.Threading.Thread.VolatileWrite(Me.m_Thread, System.Threading.Thread.CurrentThread)

        Dim ds As New DataSet()
        Using da As New SqlDataAdapter(CStr(Sql), "---CONNECTIONSTRING---")
                da.Fill(ds, "t1")
        End Using

        System.Threading.Thread.VolatileWrite(Me.m_Thread, Nothing)
        Me.BeginInvoke(New Action(Of DataSet)(AddressOf Me.EndLoadData), ds)
End Sub

Private Sub EndLoadData(ByVal data As DataSet)

        Me.DataGridView1.DataSource = data
        Me.DataGridView1.DataMember = "t1"

        'Hide 'please wait...' or '.gif' file etc...
        '????.Visible = False
        'Me.Enabled = True

End Sub

---

اول از همه ممنون برای وقتی که میذارید.
در مورد به هم ریختن کد با این کد جدیدی که دادید میتونم حلش کنم .ممنون

بله در مورد اینکه اطلاعات سریع لود میشه من هم با شما موافقم . در واقع فکر کنم مشکل اصلی که برای من به وجود میاد به خاطر اینه که من اطلاعات رو قصد دارم از اینترنت و یک سرور روی نت بخونم به همین دلیل گفتم شاید در خوندن اطلاعات به دلیل سرعت اینترنت کمی زمان بر باشه .
مورد دیگه ای که ممکنه پیش بیاد اینه که وقتی میخواد به سرور متصل بشه تنظیمات کانکشن استرینگ روی 30 ثانیه هست و در صورتی که به هردلیلی مثلا قطع بودن یا کند بودن سرعت اینترنت نتونه اطلاعات رو دریافت کنه در این صورت وقتی روی دکمه ی جست و جو کلیک کنه در این 30 ثانیه به نوعی برنامه گیر میکنه و دیگه نمیشه کاری انجام داد تا اون 30 ثانیه بگذره و بگه که ارتباط برقرار نشد . در این مورد راه کار چیه ؟!!

ببخشید یک سوال دیگه هم داشتم ولی نمیدونستم عنوانش رو چی بذارم . در همینجا مطرح میکنم با اجازتون .


من در فرمم حدود 15 تا چک باکس قرار دادم برای جست و جو که بشه عملیات جست و جو رو بر اساس فیلد های مختلف انجام بشه .
مثلا تعیین کنه که جست و جو بر اساس نام،نام خانوادگی،تلفن،کد ملی و . . .
ولی نمیدونم چه طور باید این کد هایی که دارم رو قرار بدم . درواقع مشکل من اینجاست که چه طور بفهمم کدام یک از چک باکس ها فعال هست و بعد بر اساس اون ها کد جست و جو رو قرار بدم.
برای مثال ممکنه هر 15 تا چک باکس فعال باشه و یا چک باکس های 1،5،7،9،12 فعال باشه .
پیشنهاد شما استفاده از چه دستوری است. من خواستم از دستور IF استفاده کنم که دیدم خیلی تو در تو و پیچیده میشه .
حالا اگه همه چک باکس ها فعال باشند زیاد مشکلی نیست اما اینکه کد رو برای حالت های مختلف تعداد چک باکس های فعال تنظیم کنیم سخته . ممکنه 2 چک باکس فعال باشه ( این دو چک باکس هم میتونه تعداد زیادی حالت داشته باشه. مثلا چک باکس 1 و 2 یا چک باکس 2 و 4 و یا چک بامس 10 و 5 )
امیدوارم منظورمو درست رسونده باشم.
در واقع مشکل اصلی فکر کنم انتخاب اینه که از چه ساختاری استفاده کنیم. مثلا IF , Select case , For و . . . .

سلام

نقل قول:

---

در این مورد راه کار چیه ؟!!

---

دو زمان timeout یکی برای ارتباط و یکی برای اجرا قابل تنظیم است.
timeout ارتباط از طریق connectionstring انجام میشود:

کد:

---

;Connect Timeout=60;

---

و timeout اجرا را هم میتوانید مستقیم تغییر دهید:

کد:

---

da.SelectCommand.CommandTimeout = 60

---

نقل قول:

---

از چه ساختاری استفاده کنیم

---

ساختارهایی با پایه تفکری مانند این گمانم مشکلتان را حل کند:
البته میتوانید الگو را گرفته و تغییرات بسیاری بدهید

کد:

---

Dim ds As New DataSet()
Dim sql As New System.Text.StringBuilder()
sql.Append("SELECT * FROM [tablrname] WHERE (1=1)")

Using da As New SqlDataAdapter(String.Empty, "---CONNECTIONSTRING---")
        da.SelectCommand.CommandTimeout = 60
        Dim prms = da.SelectCommand.Parameters

        If (Me.CheckBox1.Checked) Then
                sql.Append(" AND [fieldname1]=@PARAM_1")
                prms.AddWithValue("@PARAM_1", Me.TextBox1.Text)
        End If

        If (Me.CheckBox2.Checked) Then
                sql.Append(" AND [fieldname2]=@PARAM_2")
                prms.AddWithValue("@PARAM_2", Me.TextBox2.Text)
        End If

        If (Me.CheckBox3.Checked) Then
                sql.Append(" AND [fieldname3]=@PARAM_3")
                prms.AddWithValue("@PARAM_3", Me.TextBox3.Text)
        End If

        '...

        da.SelectCommand.CommandText = sql.ToString()
        da.Fill(ds)
End Using

---

موفق باشید.

ممنون .

در مورد :

کد:

---

da.SelectCommand.CommandTimeout = 60

---

این 60 یعنی چی؟! یعنی 60 ثانیه منتظر می ماند که دستور اس کیو ال که برای جست و جو داده ایم اجرا شود . و در صورتی که از این 60 ثانیه بگذرد دستور لغو می شود؟ و یا یک همچین چیزی و یا حتی 60 ثانیه منتظر می ماند که ارتباط به دیتابیس برقرار شود؟!
در صورتی که این چنین باشد تغییری در اصل مسئله نمی کند و باز هم یک 60 ثانیه زمان انتظار به وجود آمده که کاربر باید صبر کند.
شاید من متوجه این قطعه کد و منظورتون نشدم. :n13:

اما در مورد کد شرطی . ممنون از راهنماییتون. :n16: