BackUp گرفتن از دیتابیس Access

سلام دوستان

من می خواستم در برنامم از طریق کد نویسی بتونم از بانک اطلاعاتی access بکاپ بگیرم و اون رو در پوشه ای به نام DbBackUp در root برنامه کپی کنم و کاربر هر موقع خواست بتونه از اون بکاپ استفاده کنه

برای نسخه پشتیبان اکسس همون کپی کردن فایل اکسس و دوباره خوندنش کفایت میکنه

مثلا برای تهیه نسخه پشتیبان

کد:

---


File.Copy(System.Windows.Forms.Application.StartupPath + "\DB.MDB",  "c:\DBBackup\DATA.BAK", True)


---

و برای بازیابی

کد:

---


File.Copy("c:\DBBackup\DATA.BAK",System.Windows.Forms.Application.StartupPath + "\DB.MDB",  True)



---

سلام دوستان

جناب MTPROG ممنون از جواب شما

می خواستم بپرسم آیا می شه این فایل بکاپ به صورت zip شده و با پسورد در مسیر مشخص شده کپی بشه
و در هنگام بازیابی دوباره از حالت zip خارج بشه و در مسیر مشخص قرار بگیره

سلام

دوستان سوال بالای من اصلاً امکان پذیز هست

نقل قول:

---

می خواستم بپرسم آیا می شه این فایل بکاپ به صورت zip شده و با پسورد در مسیر مشخص شده کپی بشه
و در هنگام بازیابی دوباره از حالت zip خارج بشه و در مسیر مشخص قرار بگیره

---

بله میشه ولی شما باید کامپونینت مربوط به فایلهای فشرده رو داشته باشی من یه نمونه تو سایت

کد:

---

www.CodeProject.Com

---

دیدم بهتره یه سری به اونجا بزنی

نقل قول:

---

نوشته شده توسط MTPROG [ برای مشاهده لینک ، با نام کاربری خود وارد شوید یا ثبت نام کنید ]

بله میشه ولی شما باید کامپونینت مربوط به فایلهای فشرده رو داشته باشی من یه نمونه تو سایت

کد:

---

www.CodeProject.Com

---

دیدم بهتره یه سری به اونجا بزنی

---

سلام

ممنون از این سایتی که معرفی کردید

ولی واقعیتش رو بخواید من هر چی سرچ کردم چیزی دستگیرم نشد میشه لطف کنید و یه توضیح بدین

در خود VB.NET میشه از System.IO.Compression جهت فشرده سازی استفاده کرد

کد:

---

Imports System.IO
Imports System.IO.Compression

Namespace ECP

Public Class ZipUtility

    Public Sub CompressFile(ByVal sourceFile As String, ByVal destinationFile As String)

        ' make sure the source file is there
        If Not File.Exists(sourceFile) Then
            Throw New FileNotFoundException
        End If

        ' Create the streams and byte arrays needed
        Dim buffer As Byte() = Nothing
        Dim sourceStream As FileStream = Nothing
        Dim destinationStream As FileStream = Nothing
        Dim compressedStream As GZipStream = Nothing

        Try
            ' Read the bytes from the source file into a byte array
            sourceStream = New FileStream(sourceFile, FileMode.Open, FileAccess.Read, FileShare.Read)

            ' Read the source stream values into the buffer
            buffer = New Byte(sourceStream.Length) {}
            Dim checkCounter As Integer = sourceStream.Read(buffer, 0, buffer.Length)

            ' Open the FileStream to write to
            destinationStream = New FileStream(destinationFile, FileMode.OpenOrCreate, FileAccess.Write)

            ' Create a compression stream pointing to the destiantion stream
            compressedStream = New GZipStream(destinationStream, CompressionMode.Compress, True)

            'Now write the compressed data to the destination file
            compressedStream.Write(buffer, 0, buffer.Length)

        Catch ex As ApplicationException
            MessageBox.Show(ex.Message, "An Error occured during compression", MessageBoxButtons.OK, MessageBoxIcon.Error)
        Finally
            ' Make sure we allways close all streams
            If  sourceStream IsNot Nothing Then
                sourceStream.Close()
            End If
            If  compressedStream IsNot Nothing Then
                compressedStream.Close()
            End If
            If  destinationStream IsNot Nothing Then
                destinationStream.Close()
            End If
        End Try

    End Sub

    Public Sub DecompressFile(ByVal sourceFile As String, ByVal destinationFile As String)

        ' make sure the source file is there
        If Not File.Exists(sourceFile)  Then
            Throw New FileNotFoundException
        End If

        ' Create the streams and byte arrays needed
        Dim sourceStream As FileStream = Nothing
        Dim destinationStream As FileStream = Nothing
        Dim decompressedStream As GZipStream = Nothing
        Dim quartetBuffer As Byte() = Nothing

        Try
            ' Read in the compressed source stream
            sourceStream = New FileStream(sourceFile, FileMode.Open)

            ' Create a compression stream pointing to the destiantion stream
            decompressedStream = New GZipStream(sourceStream, CompressionMode.Decompress, True)

            ' Read the footer to determine the length of the destiantion file
            quartetBuffer = New Byte(4) {}
            Dim position As Integer = CType(sourceStream.Length, Integer) - 4
            sourceStream.Position = position
            sourceStream.Read(quartetBuffer, 0, 4)
            sourceStream.Position = 0
            Dim checkLength As Integer = BitConverter.ToInt32(quartetBuffer, 0)

            Dim buffer(checkLength + 100) As Byte
            Dim offset As Integer = 0
            Dim total As Integer = 0

            ' Read the compressed data into the buffer
            While True
                Dim bytesRead As Integer = decompressedStream.Read(buffer, offset, 100)
                If bytesRead = 0 Then
                    Exit While
                End If
                offset += bytesRead
                total += bytesRead
            End While

            ' Now write everything to the destination file
            destinationStream = New FileStream(destinationFile, FileMode.Create)
            destinationStream.Write(buffer, 0, total)

            ' and flush everyhting to clean out the buffer
            destinationStream.Flush()

        Catch ex As ApplicationException
            MessageBox.Show(ex.Message, "An Error occured during compression", MessageBoxButtons.OK, MessageBoxIcon.Error)
        Finally
            ' Make sure we allways close all streams
            If sourceStream IsNot Nothing Then
                sourceStream.Close()
            End If
            If decompressedStream IsNot Nothing Then
                decompressedStream.Close()
            End If
            If destinationStream IsNot Nothing Then
                destinationStream.Close()
            End If
        End Try

    End Sub
End Class
End Namespace

---