محدوديت سايز عكس

سلام
من با vb.net كار ميكنم..تو صفحه ي عضويتم وقتي كه كاربر عكسي را آپلود ميكنه عكسش را در ابعاد 150 * 200 نمايش ميده و با اندازه ي اصلي داخل فولدر آپلودم ذخيره ميشه!!!
حالا من ميخوام اين عكس با همين ابعاد داخل فولدر آپلودم ذخيره بشه نه با ابعاد اصليش
بايد چيكار كنم؟؟؟؟
تشكر:20:

سلام
شما خیلی راحت میتوانید stream تصویر را در سرور بار گذاری کنید و هم متوجه شوید که فایل ارسالی آیا حقیقتاً یک تصویر است و هم از ابعاد ان مطمئن شوید و در صورت نیاز ابعاد ان را تغییر دهید.

کد:

---

Using img As System.Drawing.Image = System.Drawing.Image.FromStream(Me.FileUpload1.PostedFile.InputStream)
    Dim w As Integer = img.Width
    Dim h As Integer = img.Height
End Using

---

در صورت بزرگتر بودن یکی از راه های تغییر سایز تصویر استفاده از متد GetThumbnailImage است. و در نهایت با متد Svae تصویر را به فرمت دلخواه و در مسیر مشخص ذخیره کنید:

کد:

---

Using smallimg As System.Drawing.Image = img.GetThumbnailImage(200, 150, Nothing, Nothing)
    smallimg.Save("C:\file.jpg", System.Drawing.Imaging.ImageFormat.Jpeg)
End Using

---

=====

مثلاً فقط به عنوان نمونه به کد زیر دقت کنید:

کد:

---

Private Const DIRUPLOAD As String = "~\Avatars\"
Private Shared ReadOnly IMGSIZEMAX As New System.Drawing.Size(200, 150)
Private Const FILESIZEMAX As Integer = 256 * 1024

Public Function Upload(ByVal file As System.Web.HttpPostedFile, ByVal ID_User As Integer) As Boolean
    Try
        Dim extension As String = System.IO.Path.GetExtension(file.FileName)
        If _
            (file.ContentLength <= 0) OrElse _
            (file.ContentLength > FILESIZEMAX) OrElse _
            (extension Is Nothing) OrElse _
            (extension.Length <= 1) _
            Then Return False

        Dim filepath As String = Me.MapPath(DIRUPLOAD & ID_User.ToString() & ".gif")
        Using img As System.Drawing.Image = System.Drawing.Image.FromStream(file.InputStream)
            If (img.Width <= 0) OrElse (img.Height <= 0) Then Return False

            If (img.Width <= IMGSIZEMAX.Width) AndAlso (img.Height <= IMGSIZEMAX.Height) Then
                If (extension.ToLower() = ".gif") Then
                    file.SaveAs(filepath)
                Else
                    img.Save(filepath, System.Drawing.Imaging.ImageFormat.Gif)
                End If

                Return True
            End If

            Dim percent As Single = System.Math.Min(CSng(IMGSIZEMAX.Width) / img.Width, CSng(IMGSIZEMAX.Height) / img.Height)
            If (percent <= 0.0F) Then Return False

            Using smallimg As System.Drawing.Image = img.GetThumbnailImage(CInt(img.Width * percent), CInt(img.Height * percent), Nothing, Nothing)
                smallimg.Save(filepath, System.Drawing.Imaging.ImageFormat.Gif)
                Return True
            End Using
        End Using
    Catch
        Return False
    End Try
End Function

---

(مقدار True مشخص کننده انجام موفقیت آمیز است)
که با دستوری مثل این قابل اجرا استفاده است:

کد:

---

Private Sub Button1_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles Button1.Click
    Me.Response.Write(Me.Upload(Me.FileUpload1.PostedFile, 14))
End Sub

---

=====

کد فوق به نوعی مخصوص آپلود تصاویر کوچک اعضا نوشته شده (آواتار).

- اول مقادیر ورودی را چک میکنید
)سایز فایل ثفر نباشد.
)سایز فایل بیش از 256K نباشد (انجام عملیات گرافیکی و کوچک کردن فایلهای بسیار بزرگ در سرور میتواند موجب کاهش بازدهی سایت شود و حتی راه نفوذی برای بدخواهان باشد تا ترافیک سایت را افزایش داده و مشکلات کم بود RAM ایجاد کنند.
)فایل داری پسوندی مجاز باشد.

- بعید مسیر ذخیره فایل را به دست می آوریم
فرض شده همه فایلها در یک پوشه و با یک پسوند واحد و با نام عدد عضویت ذخیره شده اند.
(این فرضیات بعداً کار نمایش تصاویر را خیلی ساده میکند.)

- تصویر در img بارگذاری میشود.

- اگر تصویر در محدوده ابعاد مجاز باشد و فرمتش هم gif باشد، یکراست ذخیره میشود (این عمل مانع حذف انیمیشن های احتمالی gif میشود.)

- اگر تصویر در محدوده ابعاد مجاز باشد ولی فرمتش gif نباشد، با فرمت gif ذخیره خواهد شد.
(البته در یک سیستم کامل و امن نباید به پسوند فایل که در نام آماده اعتماد کرد ولی فعلاً بیخیال!)

- در نهایت اگر تصویر بزرگتر باشد، برای حفظ نسبت طول به عرض عدد percent محاسبه شده و تصویر به سایز کوچک جدید ساخته و ذخیره میشود.

=====

این فقط یک نمونه برای یادگیری بهتر روشهای و امکانات متنوع دات نت بود.

در خیلی از موارد تصاویر کوچک را در بانک های اطلاعاتی ذخیره میکنند ولی ذخیره صحیح با در نظر گرفتن تمام جنبه ها در هارد هم مشکلی ندارد.
موفق باشید.

سلام.
من اولين كد را درون دكمه ي آپلودم گذاشتم زير Me.FileUpload1 خط ميكشه!چرا؟؟

سلام

نقل قول:

---

من اولين كد را درون دكمه ي آپلودم گذاشتم زير Me.FileUpload1 خط ميكشه!چرا؟؟

---

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
خوب نمیخواهید یه کنترلر FileUpload هم روی صفحه وبتان قرار دهید؟ کاربر با چی باید فایل را آپلود کند؟

نقل قول:

---

نوشته شده توسط _H2_ [ برای مشاهده لینک ، با نام کاربری خود وارد شوید یا ثبت نام کنید ]

سلام

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
خوب نمیخواهید یه کنترلر FileUpload هم روی صفحه وبتان قرار دهید؟ کاربر با چی باید فایل را آپلود کند؟

---

كنترلر FileUpload را گذاشته بودم.فقط نامش متفاوت بود.اصلاً حواسم به اين مورد نبود.
ببخشيد-مرسي:20:

Using smallimg As System.Drawing.Image = img.GetThumbnailImage(200, 150, Nothing, Nothing)
smallimg.Save("C:\file.jpg", System.Drawing.Imaging.ImageFormat.Jpeg)
End Using

سلام.
من ميخوام از اين روش استفاده كنم ولي ميخوام نام عكسهاي ذخيره شده هر بار متفاوت باشه اينجوري عكسها جايگزين ميشن!
آدرس حتماً بايد كامل باشه نميتونم آدرس نسبي بدم.
مرسي

سلام
اینکه مسئله مهمی نیست!
شما میتوانید از هر نام دلخواهی استفاده کنید، مسیر را هم به راحتی با Me.MapPath میتوانید به مسیر مطلق تغییر دهید.
(همانطور که اگر دقت کنید در سورس نمونه انجام شده.)