قرار دادن برنامه در - System tray-tray bar

سلام چه طور میشه برنامه رو در System tray قرار داد و دوباره نشان داد
ممنون

سلام.

کد:

---

Private Declare Function Shell_NotifyIcon Lib "shell32" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean
Private Const NIM_ADD = &H0
Private Const NIM_MODIFY = &H1
Private Const NIM_DELETE = &H2
Private Const NIF_MESSAGE = &H1
Private Const NIF_ICON = &H2
Private Const NIF_TIP = &H4

Private Const WM_LBUTTONDBLCLK = &H203
Private Const WM_LBUTTONDOWN = &H201
Private Const WM_RBUTTONUP = &H205

Private Type NOTIFYICONDATA
    cbSize As Long
    hwnd As Long
    uID As Long
    uFlags As Long
    uCallbackMessage As Long
    hIcon As Long
    szTip As String * 64
End Type

Dim TrayIcon As NOTIFYICONDATA

Private Sub Form_Load()
    TrayIcon.cbSize = Len(TrayIcon)
    TrayIcon.hwnd = picIcon.hwnd
    TrayIcon.uID = 1&
    TrayIcon.uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
    TrayIcon.uCallbackMessage = WM_LBUTTONDOWN
    TrayIcon.hIcon = picIcon.Picture
    TrayIcon.szTip = "P30World"
    Shell_NotifyIcon NIM_ADD, TrayIcon
End Sub

Private Sub picIcon_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Msg = X / Screen.TwipsPerPixelX
    If Msg = WM_LBUTTONDBLCLK Then
        MsgBox "Left button double click", 0
    ElseIf Msg = WM_RBUTTONUP Then
        MsgBox "Right button click", 0
    End If
End Sub

Private Sub Form_Unload(Cancel As Integer)
    Shell_NotifyIcon NIM_DELETE, TrayIcon
End Sub

---