استفاده از يك كامپوننت TFrames و نمايش چندين فريم بوسيله اون

سلام
مي خوام يه پنجره اي مثل پنجره تنظيمات اغلب برنامه ها بسازم مثلا مثل شكل زير كه براي Download Accolator هستش:

[ برای مشاهده لینک ، با نام کاربری خود وارد شوید یا ثبت نام کنید ]

خودم يه پنجره ساختم و در سمت چپش يه Treeview گزاشتم. و در سمت راستش هم يه Frame. مسلماً براي هر گزينه يه فريم ساختم.
مي خوام اينو بدونم براي هر گزينه از Treeview بايد يه كامپوننت فريم به فرمم اضافه كنم؟ نميشه با همين يكي كامپوننت Frame كه از تب Standard ميارمش ، بشه با چند تا فريم كار كرد؟ آخه وقتي اين كامپوننت رو به فرم اضافه مي كنيم، فقط مي تونيم يك فريم رو باهاش نمايش بديم.

هر یک از Frame ها را ایجاد کنید و نام یونیت آنها را در بخش uses از Interface یونیت فرم مورد نظر خودتون وارد کنید. حالا می تونید با تعریف یک Class Reference از TFrame مشکل خودتون رو حل کنید. نمونه کد شما مثل کد زیر میشه. در این کد Panel1 محلی هست که Frame ها در اون نمایش داده میشند. Button1 یک Frame فرضی به نام MyFrame را در داخل Panel1 نمایش میده. Button2 هم نام Frame ایی که در حال حاضر در حال نمایش هست رو برمیگردونه. برای تغییر Frame جاری کافی هست که نام کلاس آن را به خصوصیت CurrentFrame بدید:

کد:

---

type
  TFrameClass = class of TFrame;

  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    FDetailPanel : TPanel;
    FCurrFrame : TFrame;

    procedure SetCurrFrame(Value: TFrameClass);
    function GetCurrFrame: TFrameClass;
  public
    property CurrentFrame: TFrameClass read GetCurrFrame write SetCurrFrame;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
begin
  FDetailPanel := Panel1;
  CurrentFrame := TFrame;
end;

function TForm1.GetCurrFrame: TFrameClass;
begin
  Result := TFrameClass(FCurrFrame.ClassType);
end;

procedure TForm1.SetCurrFrame(Value: TFrameClass);
begin
  if Assigned(FCurrFrame) then
    FreeAndNil(FCurrFrame);

  if not Assigned(Value) then
    Exit;

  FCurrFrame := Value.Create(Self);
  try
    if not Assigned(FDetailPanel) then
      raise Exception.Create('No parent is available');
    FCurrFrame.Parent := FDetailPanel;
    FCurrFrame.Align := alClient;
    FCurrFrame.Show;
  except
    //Handle exceptions here if needed.
    raise;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  CurrentFrame := TMyFrame;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  ShowMessage(CurrentFrame.ClassName);
end;

---