Printable View
سلام
فرض کنید می خوام از داخل برنامه خودم یه
فایل exe دیگه رو فراخوانی کنم
باید چکار کنم تا قبل از این که اون فایل بسته نشده
برنامه من اجرا نشه
مثلا قبل از این که فرم اصلی برنامه نشون داده بشه
یه فایل word باز بشه بعد از این که کاربر اون فایل
رو بست ، برنامه ، صفحه اصلی نشون داده بشه
و تا موقعیکه کاربر اون رو نبسته نتونه وارد برنامه بشه
ممنون
سلامنقل قول:
وقتي برنامه شما اجرا شده و يك برنامه ديگر را اجرا كرده، پس برنامه شما در حال اجرا است!
به اين دو روش ميتوانيد يك برنامه خارجي را اجرا كنيد، سپس برنامه شما منتظر بسته شدن آن برنامه مي ماند، پس از بسته شدن ، بقيه برنامه شما اجرا مي شود.
روش اول :
روش دوم :کد:procedure ExecNewProcess(ProgramName: string);
var
StartInfo: TStartupInfo;
ProcInfo: TProcessInformation;
CreateOK: Boolean;
begin
{ fill with known state }
FillChar(StartInfo, SizeOf(TStartupInfo), #0);
FillChar(ProcInfo, SizeOf(TProcessInformation), #0);
StartInfo.cb := SizeOf(TStartupInfo);
CreateOK := CreateProcess(nil, PChar(ProgramName), nil, nil, False,
CREATE_NEW_PROCESS_GROUP + NORMAL_PRIORITY_CLASS,
nil, nil, StartInfo, ProcInfo);
{ check to see if successful }
if CreateOK then
//may or may not be needed. Usually wait for child processes
WaitForSingleObject(ProcInfo.hProcess, INFINITE);
end;
کد:{--WinExecAndWait32V2 ------------------------------------------------}
{: Executes a program and waits for it to terminate
@Param FileName contains executable + any parameters
@Param Visibility is one of the ShowWindow options, e.g. SW_SHOWNORMAL
@Returns -1 in case of error, otherwise the programs exit code
@Desc In case of error SysErrorMessage( GetlastError ) will return an
error message. The routine will process paint messages and messages
send from other threads while it waits.
-----------------------------------------------------------------------}
function WinExecAndWait32V2(FileName: string; Visibility: Integer): DWORD;
procedure WaitFor(processHandle: THandle);
var
Msg: TMsg;
ret: DWORD;
begin
repeat
ret := MsgWaitForMultipleObjects(1, { 1 handle to wait on }
processHandle, { the handle }
False, { wake on any event }
INFINITE, { wait without timeout }
QS_PAINT or { wake on paint messages }
QS_SENDMESSAGE { or messages from other threads }
);
if ret = WAIT_FAILED then Exit; { can do little here }
if ret = (WAIT_OBJECT_0 + 1) then
begin
{ Woke on a message, process paint messages only. Calling
PeekMessage gets messages send from other threads processed. }
while PeekMessage(Msg, 0, WM_PAINT, WM_PAINT, PM_REMOVE) do
DispatchMessage(Msg);
end;
until ret = WAIT_OBJECT_0;
end; { Waitfor }
var { V1 by Pat Ritchey, V2 by P.Below }
zAppName: array[0..512] of char;
StartupInfo: TStartupInfo;
ProcessInfo: TProcessInformation;
begin { WinExecAndWait32V2 }
StrPCopy(zAppName, FileName);
FillChar(StartupInfo, SizeOf(StartupInfo), #0);
StartupInfo.cb := SizeOf(StartupInfo);
StartupInfo.dwFlags := STARTF_USESHOWWINDOW;
StartupInfo.wShowWindow := Visibility;
if not CreateProcess(nil,
zAppName, { pointer to command line string }
nil, { pointer to process security attributes }
nil, { pointer to thread security attributes }
False, { handle inheritance flag }
CREATE_NEW_CONSOLE or { creation flags }
NORMAL_PRIORITY_CLASS,
nil, { pointer to new environment block }
nil, { pointer to current directory name }
StartupInfo, { pointer to STARTUPINFO }
ProcessInfo) { pointer to PROCESS_INF } then
Result := DWORD(-1) { failed, GetLastError has error code }
else
begin
Waitfor(ProcessInfo.hProcess);
GetExitCodeProcess(ProcessInfo.hProcess, Result);
CloseHandle(ProcessInfo.hProcess);
CloseHandle(ProcessInfo.hThread);
end; { Else }
end; { WinExecAndWait32V2 }
procedure TForm1.Button1Click(Sender: TObject);
begin
WinExecAndWait32V2('notepad.exe', SW_SHOWNORMAL);
end;
سلام
خیلی ممنون به خاطر کد
با اجازه من يك سوال ديگه هم ضميمه كنم كه گاهي به درد ميخوره ولي خودم براش راهي سراغ ندارم.
چط.ري ميشه يك فايل Exe ديگه رو از توي برنامه خودمون اجرا كنيم ولي توي يكي از فرمهاي برنامه خودمون اجرا بشه. نه توي يك ويندوي مستقل ديگه ؟؟؟
سلام
باید از OLE Object استفاده کنی ، توی قسمت کامپوننتهای دلفی هست ...نقل قول:
با اجازه من يك سوال ديگه هم ضميمه كنم كه گاهي به درد ميخوره ولي خودم براش راهي سراغ ندارم.
چط.ري ميشه يك فايل Exe ديگه رو از توي برنامه خودمون اجرا كنيم ولي توي يكي از فرمهاي برنامه خودمون اجرا بشه. نه توي يك ويندوي مستقل ديگه ؟؟؟
در مورد کدهای جناب NonForce هم ، کد دوم بهتر و کاملتر هست و من توصیه می کنم از اون استفاده کنید ...
موفق باشید ...
سلامنقل قول:
يك روش :
کد:procedure TForm1.Button1Click(Sender: TObject);
var
wnd: HWND;
begin
WinExec('notepad.exe', sw_hide);
Sleep(500);
wnd := FindWindow('notepad', nil);
Windows.SetParent(wnd, handle);
SetWindowPos(wnd, 0, 0, 0, clientwidth div 2, clientheight div 2, SWP_NOZORDER or
SWP_SHOWWINDOW);
end;